sp_helpxactsetjob (Transact-SQL MetaData) Definition

Please note: that the following source code is provided and copyrighted by Microsoft and is for educational purpose only.
The meta data is from an SQL 2012 Server.

I have posted alot more, find the whole list here.

Goto Definition or MetaData

Definition:

sys.sp_helpxactsetjob(nvarchar @publisher)

MetaData:

   
--   
--  Name:  
--         sp_helpxactsetjob  
--   
--  Description:  
--         Return current settings for the xactset Job  
--   
--  Inputs:  
--         @publisher        == name of heterogeneous publisher  
--   
--  Returns:  
--         Return code (0 for success, 1 for failure)  
--   
--  Security:  
--         public --  call must be sysadmin  
--   
--  Notes:  
--         This stored procedure is provided so that the administrator of   
--         heterogeneous publishing can examine the current settings associated   
--       with the xactset job.  
--   
  
CREATE PROCEDURE sys.sp_helpxactsetjob  
(  
    @publisher        sysname  
)  
AS  
BEGIN  
    DECLARE @cmd            nvarchar(4000)  
    DECLARE @retcode        int  
    DECLARE @publisher_type    sysname  
  
    --  Security Check  
    IF IS_SRVROLEMEMBER ('sysadmin') != 1  
    BEGIN  
        --  "Only members of the sysadmin fixed server role can perform this operation."  
        RAISERROR(21089,16,-1)  
        RETURN 1  
    END  
      
    SET @retcode = 0  
  
    EXEC @retcode = sys.sp_MSrepl_getpublisherinfo    @publisher        = @publisher,  
                                                    @rpcheader        = @cmd OUTPUT,  
                                                    @publisher_type    = @publisher_type OUTPUT,  
                                                    @hreplOnly        = 1  
      
    IF @retcode <> 0  
        RETURN (@retcode)  
  
    --  Error if the publisher is not a heterogeneous publisher  
    IF @publisher_type NOT LIKE 'ORACLE%'  
    BEGIN  
        RAISERROR (21696, 16, -1, @publisher, @publisher_type)  
        RETURN (1)  
    END  
  
    SET @publisher = UPPER(@publisher) COLLATE DATABASE_DEFAULT  
    set @cmd = @cmd + N'sys.sp_ORAhelpXactSetJob'  
      
    EXEC @retcode = @cmd    @publisher  
    RETURN (@retcode)  
END